O CDOSYS é um componente CDO (Collaboration Data Objects) usado para envio de e-mails no Windows Server 2003. Ele é parte integrante do IIS6, e foi criado para substituir o antigo componente Cdonts, para envio de e-mails através do SMTP do novo IIS.

Abaixo temos um exemplo de uso do CDOSYS.

<%
'cria o objeto para o envio de e-mail
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

'cria o objeto para configuração do SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

'SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "envio.redehost.com.br"

'porta do SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

'porta do CDO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'timeout
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

objCDOSYSCon.Fields.update

'atualiza a configuração do CDOSYS para o envio do e-mail
Set objCDOSYSMail.Configuration = objCDOSYSCon

'e-mail do remetente
objCDOSYSMail.From = "eu@MeuDominio.com.br"

'e-mail do destinatário
objCDOSYSMail.To = "destinatario@dominio.com.br"

'assunto da mensagem
objCDOSYSMail.Subject = "Teste do CDOSYS"

'conteúdo da mensagem
objCDOSYSMail.TextBody = "Teste do componente CDOSYS"
'para envio da mensagem no formato html altere o TextBody para HtmlBody
'objCDOSYSMail.HtmlBody = "<b>Teste do componente CDOSYS</b>"

'objCDOSYSMail.fields.update
'envia o e-mail
objCDOSYSMail.Send

'destrói os objetos
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

response.write "E-mail enviado para destinatario@dominio.com.br ..."
%>